source: osm/applications/editors/josm/nsis/josm.nsi@ 5798

Last change on this file since 5798 was 5798, checked in by ulf, 17 years ago

add a branding image
File size: 20.7 KB
Line 
1;
2; josm.nsi
3;
4
5
6; Set the compression mechanism first.
7; As of NSIS 2.07, solid compression which makes installer about 1MB smaller
8; is no longer the default, so use the /SOLID switch.
9; This unfortunately is unknown to NSIS prior to 2.07 and creates an error.
10; So if you get an error here, please update to at least NSIS 2.07!
11SetCompressor /SOLID lzma
12
13; work with JAVA ini strings
14!include "INIStrNS.nsh"
15
16!define DEST "josm"
17
18InstType "JOSM (full install)"
19
20InstType "un.Default (keep Personal Settings and plugins)"
21InstType "un.All (remove all)"
22
23; Used to refresh the display of file association
24!define SHCNE_ASSOCCHANGED 0x08000000
25!define SHCNF_IDLIST 0
26
27; Used to add associations between file extensions and JOSM
28!define OSM_ASSOC "josm-file"
29
30; ============================================================================
31; Header configuration
32; ============================================================================
33; The name of the installer
34!define PROGRAM_NAME "JOSM"
35
36Name "${PROGRAM_NAME} ${VERSION}"
37
38; The file to write
39OutFile "${DEST}-setup-${VERSION}.exe"
40
41; Uninstall stuff (NSIS 2.08: "\r\n" don't work here)
42!define MUI_UNCONFIRMPAGE_TEXT_TOP "The following JAVA OpenStreetMap editor (JOSM) installation will be uninstalled. Click 'Next' to continue."
43
44XPStyle on
45
46
47
48; ============================================================================
49; Modern UI
50; ============================================================================
51
52!include "MUI.nsh"
53;!addplugindir ".\Plugins"
54
55; Icon of installer and uninstaller
56!define MUI_ICON "logo.ico"
57!define MUI_UNICON "logo.ico"
58
59!define MUI_COMPONENTSPAGE_SMALLDESC
60!define MUI_FINISHPAGE_NOAUTOCLOSE
61!define MUI_UNFINISHPAGE_NOAUTOCLOSE
62!define MUI_WELCOMEFINISHPAGE_BITMAP "josm-nsis-brand.bmp"
63!define MUI_WELCOMEPAGE_TEXT "This wizard will guide you through the installation of the JAVA OpenStreetMap editor (JOSM).\r\n\r\nBefore starting the installation, make sure any JOSM applications are not running.\r\n\r\nClick 'Next' to continue."
64;!define MUI_FINISHPAGE_LINK "Install WinPcap to be able to capture packets from a network!"
65;!define MUI_FINISHPAGE_LINK_LOCATION "http://www.winpcap.org"
66
67; NSIS shows Readme files by opening the Readme file with the default application for
68; the file's extension. "README.win32" won't work in most cases, because extension "win32"
69; is usually not associated with an appropriate text editor. We should use extension "txt"
70; for a text file or "html" for an html README file.
71;!define MUI_FINISHPAGE_SHOWREADME "$INSTDIR\NEWS.txt"
72;!define MUI_FINISHPAGE_SHOWREADME_TEXT "Show News"
73;!define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
74!define MUI_FINISHPAGE_RUN "$INSTDIR\josm.exe"
75;!define MUI_FINISHPAGE_RUN_NOTCHECKED
76
77
78
79;!define MUI_PAGE_CUSTOMFUNCTION_SHOW myShowCallback
80
81; ============================================================================
82; MUI Pages
83; ============================================================================
84
85!insertmacro MUI_PAGE_WELCOME
86!insertmacro MUI_PAGE_LICENSE "..\core\LICENSE"
87!insertmacro MUI_PAGE_COMPONENTS
88;Page custom DisplayAdditionalTasksPage
89!insertmacro MUI_PAGE_DIRECTORY
90!insertmacro MUI_PAGE_INSTFILES
91!insertmacro MUI_PAGE_FINISH
92
93!insertmacro MUI_UNPAGE_WELCOME
94!insertmacro MUI_UNPAGE_CONFIRM
95!insertmacro MUI_UNPAGE_COMPONENTS
96!insertmacro MUI_UNPAGE_INSTFILES
97!insertmacro MUI_UNPAGE_FINISH
98
99; ============================================================================
100; MUI Languages
101; ============================================================================
102
103!insertmacro MUI_LANGUAGE "English"
104
105; ============================================================================
106; Reserve Files
107; ============================================================================
108
109 ;Things that need to be extracted on first (keep these lines before any File command!)
110 ;Only useful for BZIP2 compression
111
112; ReserveFile "AdditionalTasksPage.ini"
113!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
114
115; ============================================================================
116; Section macros
117; ============================================================================
118!include "Sections.nsh"
119
120; ========= Macro to unselect and disable a section =========
121
122!macro DisableSection SECTION
123
124 Push $0
125 SectionGetFlags "${SECTION}" $0
126 IntOp $0 $0 & ${SECTION_OFF}
127 IntOp $0 $0 | ${SF_RO}
128 SectionSetFlags "${SECTION}" $0
129 Pop $0
130
131!macroend
132
133; ========= Macro to enable (unreadonly) a section =========
134!define SECTION_ENABLE 0xFFFFFFEF
135!macro EnableSection SECTION
136
137 Push $0
138 SectionGetFlags "${SECTION}" $0
139 IntOp $0 $0 & ${SECTION_ENABLE}
140 SectionSetFlags "${SECTION}" $0
141 Pop $0
142
143!macroend
144
145; ============================================================================
146; Command Line
147; ============================================================================
148!include "FileFunc.nsh"
149
150;!insertmacro GetParameters
151;!insertmacro GetOptions
152
153; ============================================================================
154; Directory selection page configuration
155; ============================================================================
156; The text to prompt the user to enter a directory
157DirText "Choose a directory in which to install OpenStreeMap."
158
159; The default installation directory
160InstallDir $PROGRAMFILES\JOSM\
161
162; See if this is an upgrade; if so, use the old InstallDir as default
163InstallDirRegKey HKEY_LOCAL_MACHINE SOFTWARE\JOSM "InstallDir"
164
165
166; ============================================================================
167; Install page configuration
168; ============================================================================
169ShowInstDetails show
170ShowUninstDetails show
171
172; ============================================================================
173; Functions and macros
174; ============================================================================
175
176; update file extension icons
177!macro UpdateIcons
178 Push $R0
179 Push $R1
180 Push $R2
181
182 !define UPDATEICONS_UNIQUE ${__LINE__}
183
184 IfFileExists "$SYSDIR\shell32.dll" UpdateIcons.next1_${UPDATEICONS_UNIQUE} UpdateIcons.error1_${UPDATEICONS_UNIQUE}
185UpdateIcons.next1_${UPDATEICONS_UNIQUE}:
186 GetDllVersion "$SYSDIR\shell32.dll" $R0 $R1
187 IntOp $R2 $R0 / 0x00010000
188 IntCmp $R2 4 UpdateIcons.next2_${UPDATEICONS_UNIQUE} UpdateIcons.error2_${UPDATEICONS_UNIQUE}
189UpdateIcons.next2_${UPDATEICONS_UNIQUE}:
190 System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) v (${SHCNE_ASSOCCHANGED}, ${SHCNF_IDLIST}, 0, 0)'
191 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
192
193UpdateIcons.error1_${UPDATEICONS_UNIQUE}:
194 MessageBox MB_OK|MB_ICONSTOP "Can't find 'shell32.dll' library. Impossible to update icons"
195 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
196UpdateIcons.error2_${UPDATEICONS_UNIQUE}:
197 MessageBox MB_OK|MB_ICONINFORMATION "You should install the free 'Microsoft Layer for Unicode' to update JOSM file icons"
198 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
199UpdateIcons.quit_${UPDATEICONS_UNIQUE}:
200 !undef UPDATEICONS_UNIQUE
201 Pop $R2
202 Pop $R1
203 Pop $R0
204
205!macroend
206
207; associate a file extension to an icon
208Function Associate
209 ; $R0 should contain the prefix to associate to JOSM
210 Push $R1
211
212 ReadRegStr $R1 HKCR $R0 ""
213 StrCmp $R1 "" Associate.doRegister
214 Goto Associate.end
215Associate.doRegister:
216 ;The extension is not associated to any program, we can do the link
217 WriteRegStr HKCR $R0 "" ${OSM_ASSOC}
218Associate.end:
219 pop $R1
220FunctionEnd
221
222; disassociate a file extension from an icon
223Function un.unlink
224 ; $R0 should contain the prefix to unlink
225 Push $R1
226
227 ReadRegStr $R1 HKCR $R0 ""
228 StrCmp $R1 ${OSM_ASSOC} un.unlink.doUnlink
229 Goto un.unlink.end
230un.unlink.doUnlink:
231 ; The extension is associated with JOSM so, we must destroy this!
232 DeleteRegKey HKCR $R0
233un.unlink.end:
234 pop $R1
235FunctionEnd
236
237Function .onInit
238 ;Extract InstallOptions INI files
239; !insertmacro MUI_INSTALLOPTIONS_EXTRACT "AdditionalTasksPage.ini"
240FunctionEnd
241
242;Function DisplayAdditionalTasksPage
243; !insertmacro MUI_HEADER_TEXT "Select Additional Tasks" "Which additional tasks should be done?"
244; !insertmacro MUI_INSTALLOPTIONS_DISPLAY "AdditionalTasksPage.ini"
245;FunctionEnd
246
247; ============================================================================
248; Installation execution commands
249; ============================================================================
250
251Section "-Required"
252;-------------------------------------------
253
254;
255; Install for every user
256;
257SectionIn 1 2 RO
258SetShellVarContext all
259
260SetOutPath $INSTDIR
261
262; Write the uninstall keys for Windows
263WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "DisplayVersion" "${VERSION}"
264WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "DisplayName" "JOSM ${VERSION}"
265WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "UninstallString" '"$INSTDIR\uninstall.exe"'
266WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "Publisher" "The OpenStreetMap developer community, http://www.openstreetmap.org/"
267WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "HelpLink" "mailto:newbies@openstreetmap.org."
268WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "URLInfoAbout" "http://www.openstreetmap.org/"
269WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "URLUpdateInfo" "http://wiki.openstreetmap.org/index.php/JOSM"
270WriteRegDWORD HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "NoModify" 1
271WriteRegDWORD HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "NoRepair" 1
272WriteUninstaller "uninstall.exe"
273
274; Write an entry for ShellExecute
275WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe" "" '$INSTDIR\josm.exe'
276WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe" "Path" '$INSTDIR'
277
278SectionEnd ; "Required"
279
280
281Section "JOSM" SecJosm
282;-------------------------------------------
283SectionIn 1
284SetOutPath $INSTDIR
285File "josm.exe"
286
287; XXX - should be provided/done by josm.jar itself and not here!
288SetShellVarContext current
289SetOutPath "$APPDATA\JOSM"
290
291; don't overwrite existing bookmarks
292IfFileExists preferences dont_overwrite_bookmarks
293File "bookmarks"
294dont_overwrite_bookmarks:
295
296; write reasonable defaults for some preferences
297; XXX - some of this should be done in JOSM itself, see also JOSM core, data\Preferences.java function resetToDefault()
298${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "projection" "org.openstreetmap.josm.data.projection.Epsg4326"
299${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "draw.segment.direction" "true"
300${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "layerlist.visible" "true"
301${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "selectionlist.visible" "true"
302${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "commandstack.visible" "true"
303${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "propertiesdialog.visible" "true"
304${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "osm-server.url" "http://www.openstreetmap.org/api"
305${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "laf" "com.sun.java.swing.plaf.windows.WindowsLookAndFeel"
306
307${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "validator.visible" "true"
308SectionEnd
309
310
311SectionGroup "Plugins" SecPluginsGroup
312
313Section "mappaint" SecMappaintPlugin
314;-------------------------------------------
315SectionIn 1 2
316SetShellVarContext all
317SetOutPath $APPDATA\JOSM\plugins
318File "..\plugins\dist\mappaint.jar"
319SectionEnd
320
321;Section "osmarender" SecOsmarenderPlugin
322; osmarender needs Firefox (which isn't available on all machines)
323; and often provides clipped SVG graphics - therefore it's ommited by default
324;-------------------------------------------
325;SectionIn 1 2
326;SetShellVarContext all
327;SetOutPath $APPDATA\JOSM\plugins
328;File "downloads\osmarender.jar"
329; XXX - should be done inside the plugin and not here!
330;SetShellVarContext current
331;${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "osmarender.firefox" "$PROGRAMFILES\Mozilla Firefox\firefox.exe"
332;SectionEnd
333
334Section "WMS" SecWMSPlugin
335;-------------------------------------------
336SectionIn 1 2
337SetShellVarContext all
338SetOutPath $APPDATA\JOSM\plugins
339File "..\plugins\dist\wmsplugin.jar"
340SectionEnd
341
342Section "namefinder" SecNamefinderPlugin
343;-------------------------------------------
344SectionIn 1 2
345SetShellVarContext all
346SetOutPath $APPDATA\JOSM\plugins
347File "..\plugins\dist\namefinder.jar"
348SectionEnd
349
350Section "validator" SecValidatorPlugin
351;-------------------------------------------
352SectionIn 1 2
353SetShellVarContext all
354SetOutPath $APPDATA\JOSM\plugins
355File "..\plugins\dist\validator.jar"
356SectionEnd
357
358SectionGroupEnd ; "Plugins"
359
360Section "Start Menu Entry" SecStartMenu
361;-------------------------------------------
362SectionIn 1 2
363; Create start menu entries (depending on additional tasks page)
364;ReadINIStr $0 "$PLUGINSDIR\AdditionalTasksPage.ini" "Field 2" "State"
365;StrCmp $0 "0" SecRequired_skip_StartMenu
366; To qoute "http://msdn.microsoft.com/library/default.asp?url=/library/en-us/dnwue/html/ch11d.asp":
367; "Do not include Readme, Help, or Uninstall entries on the Programs menu."
368CreateShortCut "$SMPROGRAMS\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" "JAVA OpenStreetMap - Editor"
369;SecRequired_skip_StartMenu:
370SectionEnd
371
372Section "Desktop Icon" SecDesktopIcon
373;-------------------------------------------
374; SectionIn 1 2
375; is command line option "/desktopicon" set?
376;${GetParameters} $R0
377;${GetOptions} $R0 "/desktopicon=" $R1
378;StrCmp $R1 "no" SecRequired_skip_DesktopIcon
379;StrCmp $R1 "yes" SecRequired_install_DesktopIcon
380
381; Create desktop icon (depending on additional tasks page and command line option)
382;ReadINIStr $0 "$PLUGINSDIR\AdditionalTasksPage.ini" "Field 3" "State"
383;StrCmp $0 "0" SecRequired_skip_DesktopIcon
384;SecRequired_install_DesktopIcon:
385CreateShortCut "$DESKTOP\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" "JAVA OpenStreetMap - Editor"
386;SecRequired_skip_DesktopIcon:
387SectionEnd
388
389Section "Quick Launch Icon" SecQuickLaunchIcon
390;-------------------------------------------
391SectionIn 1 2
392; is command line option "/quicklaunchicon" set?
393;${GetParameters} $R0
394;${GetOptions} $R0 "/quicklaunchicon=" $R1
395;StrCmp $R1 "no" SecRequired_skip_QuickLaunchIcon
396;StrCmp $R1 "yes" SecRequired_install_QuickLaunchIcon
397
398; Create quick launch icon (depending on additional tasks page and command line option)
399;ReadINIStr $0 "$PLUGINSDIR\AdditionalTasksPage.ini" "Field 4" "State"
400;StrCmp $0 "0" SecRequired_skip_QuickLaunchIcon
401;SecRequired_install_QuickLaunchIcon:
402CreateShortCut "$QUICKLAUNCH\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" "JAVA OpenStreetMap - Editor"
403;SecRequired_skip_QuickLaunchIcon:
404SectionEnd
405
406Section "File Extensions" SecFileExtensions
407;-------------------------------------------
408SectionIn 1 2
409; Create File Extensions (depending on additional tasks page)
410;ReadINIStr $0 "$PLUGINSDIR\AdditionalTasksPage.ini" "Field 6" "State"
411;StrCmp $0 "0" SecRequired_skip_FileExtensions
412WriteRegStr HKCR ${OSM_ASSOC} "" "OpenStreetMap data"
413WriteRegStr HKCR "${OSM_ASSOC}\Shell\open\command" "" '"$INSTDIR\josm.exe" "%1"'
414WriteRegStr HKCR "${OSM_ASSOC}\DefaultIcon" "" '"$INSTDIR\josm.exe",0'
415push $R0
416 StrCpy $R0 ".osm"
417 Call Associate
418 StrCpy $R0 ".gpx"
419 Call Associate
420; if somethings added here, add it also to the uninstall section and the AdditionalTask page
421pop $R0
422!insertmacro UpdateIcons
423;SecRequired_skip_FileExtensions:
424SectionEnd
425
426
427Section "-PluginSetting"
428;-------------------------------------------
429SectionIn 1 2
430;MessageBox MB_OK "PluginSetting!" IDOK 0
431; XXX - should better be handled inside JOSM (recent plugin manager is going in the right direction)
432SetShellVarContext current
433${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "plugins" "mappaint,wmsplugin,namefinder,validator"
434SectionEnd
435
436
437Section "Uninstall" un.SecUinstall
438;-------------------------------------------
439
440;
441; UnInstall for every user
442;
443SectionIn 1 2
444SetShellVarContext all
445
446Delete "$INSTDIR\josm.exe"
447Delete "$INSTDIR\uninstall.exe"
448Delete "$APPDATA\JOSM\plugins\wmsplugin.jar"
449;Delete "$APPDATA\JOSM\plugins\osmarender.jar"
450Delete "$APPDATA\JOSM\plugins\mappaint.jar"
451Delete "$APPDATA\JOSM\plugins\namefinder.jar"
452Delete "$APPDATA\JOSM\plugins\validator.jar"
453RMDir "$APPDATA\JOSM\plugins"
454RMDir "$APPDATA\JOSM"
455IfErrors 0 NoJOSMErrorMsg
456 MessageBox MB_OK "Please note: josm.exe could not be removed, it's probably in use!" IDOK 0 ;skipped if josm.exe removed
457 Abort "Please note: josm.exe could not be removed, it's probably in use! Abort uninstall process!"
458NoJOSMErrorMsg:
459
460DeleteRegKey HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM"
461DeleteRegKey HKEY_LOCAL_MACHINE "Software\josm.exe"
462DeleteRegKey HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe"
463
464push $R0
465 StrCpy $R0 ".osm"
466 Call un.unlink
467 StrCpy $R0 ".gpx"
468 Call un.unlink
469pop $R0
470
471DeleteRegKey HKCR ${OSM_ASSOC}
472DeleteRegKey HKCR "${OSM_ASSOC}\Shell\open\command"
473DeleteRegKey HKCR "${OSM_ASSOC}\DefaultIcon"
474!insertmacro UpdateIcons
475
476Delete "$SMPROGRAMS\josm.lnk"
477Delete "$DESKTOP\josm.lnk"
478Delete "$QUICKLAUNCH\josm.lnk"
479
480RMDir "$INSTDIR"
481
482SectionEnd ; "Uinstall"
483
484Section /o "Un.Personal Settings" un.SecPersonalSettings
485;-------------------------------------------
486SectionIn 2
487SetShellVarContext current
488Delete "$APPDATA\JOSM\preferences"
489Delete "$APPDATA\JOSM\bookmarks"
490;Delete "$APPDATA\JOSM\de-streets.xml"
491RMDir "$APPDATA\JOSM"
492RMDir "$APPDATA\JOSM\plugins\mappaint"
493SectionEnd
494
495Section /o "Un.Personal Plugins" un.SecPlugins
496;-------------------------------------------
497SectionIn 2
498SetShellVarContext current
499Delete "$APPDATA\JOSM\plugins\wmsplugin.jar"
500;Delete "$APPDATA\JOSM\plugins\osmarender.jar"
501;Delete "$APPDATA\JOSM\plugins\osmarender\*.*"
502Delete "$APPDATA\JOSM\plugins\mappaint.jar"
503Delete "$APPDATA\JOSM\plugins\namefinder.jar"
504Delete "$APPDATA\JOSM\plugins\validator\*.*"
505Delete "$APPDATA\JOSM\plugins\validator.jar"
506;RMDir "$APPDATA\JOSM\plugins\osmarender"
507RMDir "$APPDATA\JOSM\plugins\validator"
508RMDir "$APPDATA\JOSM\plugins"
509RMDir "$APPDATA\JOSM"
510SectionEnd
511
512
513Section "-Un.Finally"
514;-------------------------------------------
515SectionIn 1 2
516; this test must be done after all other things uninstalled (e.g. Global Settings)
517IfFileExists "$INSTDIR" 0 NoFinalErrorMsg
518 MessageBox MB_OK "Please note: The directory $INSTDIR could not be removed!" IDOK 0 ; skipped if dir doesn't exist
519NoFinalErrorMsg:
520SectionEnd
521
522
523; ============================================================================
524; PLEASE MAKE SURE, THAT THE DESCRIPTIVE TEXT FITS INTO THE DESCRIPTION FIELD!
525; ============================================================================
526!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
527 !insertmacro MUI_DESCRIPTION_TEXT ${SecJosm} "JOSM is the JAVA OpenStreetMap editor for .osm files."
528 !insertmacro MUI_DESCRIPTION_TEXT ${SecPluginsGroup} "An assortment of useful JOSM plugins."
529 !insertmacro MUI_DESCRIPTION_TEXT ${SecMappaintPlugin} "An alternative renderer for the map with colouring, line thickness, icons after tags."
530; !insertmacro MUI_DESCRIPTION_TEXT ${SecOsmarenderPlugin} "Displays the current screen as nicely rendered SVG graphics in FireFox."
531 !insertmacro MUI_DESCRIPTION_TEXT ${SecWMSPlugin} "Display background images from Web Map Service (WMS) sources."
532 !insertmacro MUI_DESCRIPTION_TEXT ${SecNamefinderPlugin} "Add a 'Find places by their name' tab to the download dialog."
533 !insertmacro MUI_DESCRIPTION_TEXT ${SecValidatorPlugin} "Validates edited data if it conforms to common suggestions."
534 !insertmacro MUI_DESCRIPTION_TEXT ${SecStartMenu} "Add a JOSM start menu entry."
535 !insertmacro MUI_DESCRIPTION_TEXT ${SecDesktopIcon} "Add a JOSM desktop icon."
536 !insertmacro MUI_DESCRIPTION_TEXT ${SecQuickLaunchIcon} "Add a JOSM icon to the quick launch bar."
537 !insertmacro MUI_DESCRIPTION_TEXT ${SecFileExtensions} "Add JOSM file extensions for .osm and .gpx files."
538
539
540!insertmacro MUI_FUNCTION_DESCRIPTION_END
541
542!insertmacro MUI_UNFUNCTION_DESCRIPTION_BEGIN
543 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUinstall} "Uninstall JOSM."
544 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecPersonalSettings} "Uninstall personal settings like your preferences and bookmarks from your profile: $PROFILE."
545 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecPlugins} "Uninstall all plugins."
546!insertmacro MUI_UNFUNCTION_DESCRIPTION_END
547
548; ============================================================================
549; Callback functions
550; ============================================================================
551
Note: See TracBrowser for help on using the repository browser.