source: osm/applications/editors/josm/nsis/josm.nsi@ 14200

Last change on this file since 14200 was 14200, checked in by ulf, 15 years ago

add AgPifoJ Plugin
File size: 17.6 KB
Line 
1;
2; josm.nsi
3;
4
5; Set the compression mechanism first.
6; If you get an error here, please update to at least NSIS 2.07!
7SetCompressor /SOLID lzma
8
9; work with JAVA ini strings
10!include "INIStrNS.nsh"
11
12!define DEST "josm"
13
14; Used to refresh the display of file association
15!define SHCNE_ASSOCCHANGED 0x08000000
16!define SHCNF_IDLIST 0
17
18; Used to add associations between file extensions and JOSM
19!define OSM_ASSOC "josm-file"
20
21; ============================================================================
22; Header configuration
23; ============================================================================
24; The name of the installer
25!define PROGRAM_NAME "JOSM"
26
27Name "${PROGRAM_NAME} ${VERSION}"
28
29; The file to write
30OutFile "${DEST}-setup-${VERSION}.exe"
31
32XPStyle on
33
34
35
36; ============================================================================
37; Modern UI
38; ============================================================================
39
40!include "MUI.nsh"
41
42; Icon of installer and uninstaller
43!define MUI_ICON "logo.ico"
44!define MUI_UNICON "logo.ico"
45
46!define MUI_COMPONENTSPAGE_SMALLDESC
47!define MUI_FINISHPAGE_NOAUTOCLOSE
48!define MUI_UNFINISHPAGE_NOAUTOCLOSE
49!define MUI_WELCOMEFINISHPAGE_BITMAP "josm-nsis-brand.bmp"
50!define MUI_WELCOMEPAGE_TEXT $(JOSM_WELCOME_TEXT)
51
52!define MUI_FINISHPAGE_RUN "$INSTDIR\josm.exe"
53
54
55; ============================================================================
56; MUI Pages
57; ============================================================================
58
59!insertmacro MUI_PAGE_WELCOME
60!insertmacro MUI_PAGE_LICENSE "..\core\LICENSE"
61!insertmacro MUI_PAGE_COMPONENTS
62;Page custom DisplayAdditionalTasksPage
63!insertmacro MUI_PAGE_DIRECTORY
64!insertmacro MUI_PAGE_INSTFILES
65!insertmacro MUI_PAGE_FINISH
66
67!insertmacro MUI_UNPAGE_WELCOME
68!insertmacro MUI_UNPAGE_CONFIRM
69!insertmacro MUI_UNPAGE_COMPONENTS
70!insertmacro MUI_UNPAGE_INSTFILES
71!insertmacro MUI_UNPAGE_FINISH
72
73; ============================================================================
74; MUI Languages
75; ============================================================================
76
77 ;Remember the installer language
78 !define MUI_LANGDLL_REGISTRY_ROOT "HKLM"
79 !define MUI_LANGDLL_REGISTRY_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM"
80 !define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
81
82 ;; English goes first because its the default. The rest are
83 ;; in alphabetical order (at least the strings actually displayed
84 ;; will be).
85
86 !insertmacro MUI_LANGUAGE "English"
87 !insertmacro MUI_LANGUAGE "German"
88
89;--------------------------------
90;Translations
91
92 !define JOSM_DEFAULT_LANGFILE "locale\english.nsh"
93
94 !include "langmacros.nsh"
95
96 !insertmacro JOSM_MACRO_INCLUDE_LANGFILE "ENGLISH" "locale\english.nsh"
97 !insertmacro JOSM_MACRO_INCLUDE_LANGFILE "GERMAN" "locale\german.nsh"
98
99; Uninstall stuff
100!define MUI_UNCONFIRMPAGE_TEXT_TOP ${un.JOSM_UNCONFIRMPAGE_TEXT_TOP}
101
102; ============================================================================
103; Installation types
104; ============================================================================
105
106InstType "$(JOSM_FULL_INSTALL)"
107
108InstType "un.$(un.JOSM_DEFAULT_UNINSTALL)"
109InstType "un.$(un.JOSM_FULL_UNINSTALL)"
110
111; ============================================================================
112; Reserve Files
113; ============================================================================
114
115 ;Things that need to be extracted on first (keep these lines before any File command!)
116 ;Only useful for BZIP2 compression
117
118!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
119
120; ============================================================================
121; Section macros
122; ============================================================================
123!include "Sections.nsh"
124
125; ========= Macro to unselect and disable a section =========
126
127!macro DisableSection SECTION
128
129 Push $0
130 SectionGetFlags "${SECTION}" $0
131 IntOp $0 $0 & ${SECTION_OFF}
132 IntOp $0 $0 | ${SF_RO}
133 SectionSetFlags "${SECTION}" $0
134 Pop $0
135
136!macroend
137
138; ========= Macro to enable (unreadonly) a section =========
139!define SECTION_ENABLE 0xFFFFFFEF
140!macro EnableSection SECTION
141
142 Push $0
143 SectionGetFlags "${SECTION}" $0
144 IntOp $0 $0 & ${SECTION_ENABLE}
145 SectionSetFlags "${SECTION}" $0
146 Pop $0
147
148!macroend
149
150; ============================================================================
151; Command Line
152; ============================================================================
153!include "FileFunc.nsh"
154
155; ============================================================================
156; Directory selection page configuration
157; ============================================================================
158; The text to prompt the user to enter a directory
159DirText $(JOSM_DIR_TEXT)
160
161; The default installation directory
162InstallDir $PROGRAMFILES\JOSM\
163
164; See if this is an upgrade; if so, use the old InstallDir as default
165InstallDirRegKey HKEY_LOCAL_MACHINE SOFTWARE\JOSM "InstallDir"
166
167
168; ============================================================================
169; Install page configuration
170; ============================================================================
171ShowInstDetails show
172ShowUninstDetails show
173
174; ============================================================================
175; Functions and macros
176; ============================================================================
177
178; update file extension icons
179!macro UpdateIcons
180 Push $R0
181 Push $R1
182 Push $R2
183
184 !define UPDATEICONS_UNIQUE ${__LINE__}
185
186 IfFileExists "$SYSDIR\shell32.dll" UpdateIcons.next1_${UPDATEICONS_UNIQUE} UpdateIcons.error1_${UPDATEICONS_UNIQUE}
187UpdateIcons.next1_${UPDATEICONS_UNIQUE}:
188 GetDllVersion "$SYSDIR\shell32.dll" $R0 $R1
189 IntOp $R2 $R0 / 0x00010000
190 IntCmp $R2 4 UpdateIcons.next2_${UPDATEICONS_UNIQUE} UpdateIcons.error2_${UPDATEICONS_UNIQUE}
191UpdateIcons.next2_${UPDATEICONS_UNIQUE}:
192 System::Call 'shell32.dll::SHChangeNotify(i, i, i, i) v (${SHCNE_ASSOCCHANGED}, ${SHCNF_IDLIST}, 0, 0)'
193 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
194
195UpdateIcons.error1_${UPDATEICONS_UNIQUE}:
196 MessageBox MB_OK|MB_ICONSTOP $(JOSM_UPDATEICONS_ERROR1)
197 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
198UpdateIcons.error2_${UPDATEICONS_UNIQUE}:
199 MessageBox MB_OK|MB_ICONINFORMATION $(JOSM_UPDATEICONS_ERROR2)
200 Goto UpdateIcons.quit_${UPDATEICONS_UNIQUE}
201UpdateIcons.quit_${UPDATEICONS_UNIQUE}:
202 !undef UPDATEICONS_UNIQUE
203 Pop $R2
204 Pop $R1
205 Pop $R0
206
207!macroend
208
209; associate a file extension to an icon
210Function Associate
211 ; $R0 should contain the prefix to associate to JOSM
212 Push $R1
213
214 ReadRegStr $R1 HKCR $R0 ""
215 StrCmp $R1 "" Associate.doRegister
216 Goto Associate.end
217Associate.doRegister:
218 ;The extension is not associated to any program, we can do the link
219 WriteRegStr HKCR $R0 "" ${OSM_ASSOC}
220Associate.end:
221 pop $R1
222FunctionEnd
223
224; disassociate a file extension from an icon
225Function un.unlink
226 ; $R0 should contain the prefix to unlink
227 Push $R1
228
229 ReadRegStr $R1 HKCR $R0 ""
230 StrCmp $R1 ${OSM_ASSOC} un.unlink.doUnlink
231 Goto un.unlink.end
232un.unlink.doUnlink:
233 ; The extension is associated with JOSM so, we must destroy this!
234 DeleteRegKey HKCR $R0
235un.unlink.end:
236 pop $R1
237FunctionEnd
238
239Function .onInit
240 ;Extract InstallOptions INI files
241; !insertmacro MUI_INSTALLOPTIONS_EXTRACT "AdditionalTasksPage.ini"
242 !insertmacro MUI_LANGDLL_DISPLAY
243FunctionEnd
244
245Function un.onInit
246
247 !insertmacro MUI_UNGETLANGUAGE
248
249FunctionEnd
250
251; ============================================================================
252; Installation execution commands
253; ============================================================================
254
255Section "-Required"
256;-------------------------------------------
257
258;
259; Install for every user
260;
261SectionIn 1 2 RO
262SetShellVarContext current
263
264SetOutPath $INSTDIR
265
266; Write the uninstall keys for Windows
267WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "DisplayVersion" "${VERSION}"
268WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "DisplayName" "JOSM ${VERSION}"
269WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "UninstallString" '"$INSTDIR\uninstall.exe"'
270WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "Publisher" "The OpenStreetMap developer community, http://www.openstreetmap.org/"
271WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "HelpLink" "mailto:newbies@openstreetmap.org."
272WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "URLInfoAbout" "http://www.openstreetmap.org/"
273WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "URLUpdateInfo" "http://wiki.openstreetmap.org/index.php/JOSM"
274WriteRegDWORD HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "NoModify" 1
275WriteRegDWORD HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM" "NoRepair" 1
276WriteUninstaller "uninstall.exe"
277
278; Write an entry for ShellExecute
279WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe" "" '$INSTDIR\josm.exe'
280WriteRegStr HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe" "Path" '$INSTDIR'
281
282SectionEnd ; "Required"
283
284
285Section $(JOSM_SEC_JOSM) SecJosm
286;-------------------------------------------
287SectionIn 1
288SetOutPath $INSTDIR
289File "josm.exe"
290
291; XXX - should be provided/done by josm.jar itself and not here!
292SetShellVarContext current
293SetOutPath "$APPDATA\JOSM"
294
295; don't overwrite existing bookmarks
296IfFileExists preferences dont_overwrite_bookmarks
297File "bookmarks"
298dont_overwrite_bookmarks:
299
300; write reasonable defaults for some preferences
301; XXX - some of this should be done in JOSM itself, see also JOSM core, data\Preferences.java function resetToDefault()
302; XXX - just using JOSM defaults doesn't work here, as JOSM doesn't set some defaults if a preferences file doesn't exist
303${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "projection" "org.openstreetmap.josm.data.projection.Epsg4326"
304;${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "draw.segment.direction" "true"
305${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "layerlist.visible" "true"
306${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "selectionlist.visible" "true"
307${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "commandstack.visible" "true"
308${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "propertiesdialog.visible" "true"
309${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "osm-server.url" "http://www.openstreetmap.org/api"
310${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "laf" "com.sun.java.swing.plaf.windows.WindowsLookAndFeel"
311
312${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "validator.visible" "true"
313
314SectionEnd
315
316
317SectionGroup $(JOSM_SEC_PLUGINS_GROUP) SecPluginsGroup
318
319Section $(JOSM_SEC_AGPIFOJ_PLUGIN) SecAgPifoJPlugin
320;-------------------------------------------
321SectionIn 1 2
322SetShellVarContext current
323SetOutPath $APPDATA\JOSM\plugins
324File "..\dist\AgPifoJ.jar"
325SectionEnd
326
327Section $(JOSM_SEC_VALIDATOR_PLUGIN) SecValidatorPlugin
328;-------------------------------------------
329SectionIn 1 2
330SetShellVarContext current
331SetOutPath $APPDATA\JOSM\plugins
332File "..\dist\validator.jar"
333SectionEnd
334
335Section $(JOSM_SEC_WMS_PLUGIN) SecWMSPlugin
336;-------------------------------------------
337SectionIn 1 2
338SetShellVarContext current
339SetOutPath $APPDATA\JOSM\plugins
340File "..\dist\wmsplugin.jar"
341SetOutPath $INSTDIR\imageformats
342File "webkit-image\imageformats\qjpeg4.dll"
343SetOutPath $INSTDIR
344File "webkit-image\mingwm10.dll"
345File "webkit-image\QtCore4.dll"
346File "webkit-image\QtGui4.dll"
347File "webkit-image\QtNetwork4.dll"
348File "webkit-image\QtWebKit4.dll"
349File "webkit-image\webkit-image.exe"
350SectionEnd
351
352SectionGroupEnd ; "Plugins"
353
354Section $(JOSM_SEC_STARTMENU) SecStartMenu
355;-------------------------------------------
356SectionIn 1 2
357; To qoute "http://msdn.microsoft.com/library/default.asp?url=/library/en-us/dnwue/html/ch11d.asp":
358; "Do not include Readme, Help, or Uninstall entries on the Programs menu."
359CreateShortCut "$SMPROGRAMS\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" $(JOSM_LINK_TEXT)
360SectionEnd
361
362Section $(JOSM_SEC_DESKTOP_ICON) SecDesktopIcon
363;-------------------------------------------
364; SectionIn 1 2
365; Create desktop icon
366; Desktop icon for a program should not be installed as default!
367CreateShortCut "$DESKTOP\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" $(JOSM_LINK_TEXT)
368SectionEnd
369
370Section $(JOSM_SEC_QUICKLAUNCH_ICON) SecQuickLaunchIcon
371;-------------------------------------------
372SectionIn 1 2
373; Create quick launch icon
374CreateShortCut "$QUICKLAUNCH\JOSM.lnk" "$INSTDIR\josm.exe" "" "$INSTDIR\josm.exe" 0 "" "" $(JOSM_LINK_TEXT)
375SectionEnd
376
377Section $(JOSM_SEC_FILE_EXTENSIONS) SecFileExtensions
378;-------------------------------------------
379SectionIn 1 2
380; Create File Extensions
381WriteRegStr HKCR ${OSM_ASSOC} "" "OpenStreetMap data"
382WriteRegStr HKCR "${OSM_ASSOC}\Shell\open\command" "" '"$INSTDIR\josm.exe" "%1"'
383WriteRegStr HKCR "${OSM_ASSOC}\DefaultIcon" "" '"$INSTDIR\josm.exe",0'
384push $R0
385 StrCpy $R0 ".osm"
386 Call Associate
387 StrCpy $R0 ".gpx"
388 Call Associate
389; if somethings added here, add it also to the uninstall section
390pop $R0
391!insertmacro UpdateIcons
392SectionEnd
393
394
395Section "-PluginSetting"
396;-------------------------------------------
397SectionIn 1 2
398;MessageBox MB_OK "PluginSetting!" IDOK 0
399; XXX - should better be handled inside JOSM (recent plugin manager is going in the right direction)
400SetShellVarContext current
401!include LogicLib.nsh
402${WriteINIStrNS} $R0 "$APPDATA\JOSM\preferences" "plugins" "AgPifoJ;validator;wmsplugin"
403SectionEnd
404
405
406Section "un.$(un.JOSM_SEC_UNINSTALL)" un.SecUinstall
407;-------------------------------------------
408
409;
410; UnInstall for every user
411;
412SectionIn 1 2
413SetShellVarContext current
414
415Delete "$INSTDIR\josm.exe"
416IfErrors 0 NoJOSMErrorMsg
417 MessageBox MB_OK $(un.JOSM_IN_USE_ERROR) IDOK 0 ;skipped if josm.exe removed
418 Abort $(un.JOSM_IN_USE_ERROR)
419NoJOSMErrorMsg:
420Delete "$INSTDIR\imageformats\qjpeg4.dll"
421RMDir "$INSTDIR\imageformats"
422Delete "$INSTDIR\mingwm10.dll"
423Delete "$INSTDIR\QtCore4.dll"
424Delete "$INSTDIR\QtGui4.dll"
425Delete "$INSTDIR\QtNetwork4.dll"
426Delete "$INSTDIR\QtWebKit4.dll"
427Delete "$INSTDIR\webkit-image.exe"
428Delete "$INSTDIR\uninstall.exe"
429
430DeleteRegKey HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\Uninstall\OSM"
431DeleteRegKey HKEY_LOCAL_MACHINE "Software\josm.exe"
432DeleteRegKey HKEY_LOCAL_MACHINE "Software\Microsoft\Windows\CurrentVersion\App Paths\josm.exe"
433
434; Remove Language preference info
435DeleteRegKey HKCU "Software/JOSM" ;${MUI_LANGDLL_REGISTRY_ROOT} ${MUI_LANGDLL_REGISTRY_KEY}
436
437push $R0
438 StrCpy $R0 ".osm"
439 Call un.unlink
440 StrCpy $R0 ".gpx"
441 Call un.unlink
442pop $R0
443
444DeleteRegKey HKCR ${OSM_ASSOC}
445DeleteRegKey HKCR "${OSM_ASSOC}\Shell\open\command"
446DeleteRegKey HKCR "${OSM_ASSOC}\DefaultIcon"
447!insertmacro UpdateIcons
448
449Delete "$SMPROGRAMS\josm.lnk"
450Delete "$DESKTOP\josm.lnk"
451Delete "$QUICKLAUNCH\josm.lnk"
452
453RMDir "$INSTDIR"
454
455SectionEnd ; "Uinstall"
456
457Section /o "un.$(un.JOSM_SEC_PERSONAL_SETTINGS)" un.SecPersonalSettings
458;-------------------------------------------
459SectionIn 2
460SetShellVarContext current
461Delete "$APPDATA\JOSM\plugins\agpifoj\*.*"
462RMDir "$APPDATA\JOSM\plugins\agpifoj"
463Delete "$APPDATA\JOSM\plugins\validator\*.*"
464RMDir "$APPDATA\JOSM\plugins\validator"
465Delete "$APPDATA\JOSM\plugins\wmsplugin\*.*"
466RMDir "$APPDATA\JOSM\plugins\wmsplugin"
467Delete "$APPDATA\JOSM\plugins\*.*"
468RMDir "$APPDATA\JOSM\plugins"
469
470Delete "$APPDATA\JOSM\motd.html"
471Delete "$APPDATA\JOSM\preferences"
472Delete "$APPDATA\JOSM\bookmarks"
473RMDir "$APPDATA\JOSM"
474SectionEnd
475
476
477Section "-Un.Finally"
478;-------------------------------------------
479SectionIn 1 2
480; this test must be done after all other things uninstalled (e.g. Global Settings)
481IfFileExists "$INSTDIR" 0 NoFinalErrorMsg
482 MessageBox MB_OK $(un.JOSM_INSTDIR_ERROR) IDOK 0 ; skipped if dir doesn't exist
483NoFinalErrorMsg:
484SectionEnd
485
486
487; ============================================================================
488; PLEASE MAKE SURE, THAT THE DESCRIPTIVE TEXT FITS INTO THE DESCRIPTION FIELD!
489; ============================================================================
490!insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
491 !insertmacro MUI_DESCRIPTION_TEXT ${SecJosm} $(JOSM_SECDESC_JOSM)
492 !insertmacro MUI_DESCRIPTION_TEXT ${SecPluginsGroup} $(JOSM_SECDESC_PLUGINS_GROUP)
493 !insertmacro MUI_DESCRIPTION_TEXT ${SecAgPifoJPlugin} $(JOSM_SECDESC_AGPIFOJ_PLUGIN)
494 !insertmacro MUI_DESCRIPTION_TEXT ${SecValidatorPlugin} $(JOSM_SECDESC_VALIDATOR_PLUGIN)
495 !insertmacro MUI_DESCRIPTION_TEXT ${SecWMSPlugin} $(JOSM_SECDESC_WMS_PLUGIN)
496 !insertmacro MUI_DESCRIPTION_TEXT ${SecStartMenu} $(JOSM_SECDESC_STARTMENU)
497 !insertmacro MUI_DESCRIPTION_TEXT ${SecDesktopIcon} $(JOSM_SECDESC_DESKTOP_ICON)
498 !insertmacro MUI_DESCRIPTION_TEXT ${SecQuickLaunchIcon} $(JOSM_SECDESC_QUICKLAUNCH_ICON)
499 !insertmacro MUI_DESCRIPTION_TEXT ${SecFileExtensions} $(JOSM_SECDESC_FILE_EXTENSIONS)
500
501
502!insertmacro MUI_FUNCTION_DESCRIPTION_END
503
504!insertmacro MUI_UNFUNCTION_DESCRIPTION_BEGIN
505 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecUinstall} $(un.JOSM_SECDESC_UNINSTALL)
506 !insertmacro MUI_DESCRIPTION_TEXT ${un.SecPersonalSettings} $(un.JOSM_SECDESC_PERSONAL_SETTINGS)
507!insertmacro MUI_UNFUNCTION_DESCRIPTION_END
508
509; ============================================================================
510; Callback functions
511; ============================================================================
512
Note: See TracBrowser for help on using the repository browser.