source: osm/applications/editors/josm/i18n/launchpad.pl@ 36404

Last change on this file since 36404 was 36404, checked in by stoecker, 4 weeks ago

add eo, fix typo
  • Property svn:executable set to *
  • Property svn:keywords set to Revision
File size: 12.5 KB
Line 
1#!/usr/bin/perl -w
2# -CDSL would be better than explicit encoding settings
3
4use strict;
5use utf8;
6
7my ($user, $pwd);
8
9# Three ways to handle login data:
10 # Enter data directly in these two lines (Be careful witn svn checkin later!)
11 # create a file "launchpad.pl_credits" or ~/.josm_i18n_launchpad.pl_credits
12 # containing the two lines with proper values
13 # leave credits empty and enter them on runtime
14$user = '';
15$pwd = '';
16
17# list of supported languages
18my %lang = map {$_ => 1} (
19"ar", "ast", "bg", "be", "ca", "ca\@valencia", "cs", "cy", "da", "de",
20"el", "en_AU", "en_CA", "en_GB", "eo", "es", "et", "fa", "fi", "fr", "gl",
21"hu", "id", "is", "it", "ja", "ko", "km", "lt", "mr", "nb",
22"nl", "pl", "pt", "pt_BR", "ru", "sk", "sr\@latin", "sv", "tr", "uk",
23"zh_CN", "zh_TW"
24);
25
26my $revision = '$Revision: 36404 $';
27$revision =~ s/^.*?(\d+).*$/$1/;
28my $agent = "JOSM_Launchpad/1.$revision";
29
30my $debugfile = 0;#1;
31my $cleanall = 0;#1;
32
33open TXTFILE,">","launchpad_debug.log" or die if $debugfile;
34
35if($#ARGV != 0)
36{
37 warn "No argument given (try Launchpad download URL, \"bzr\", \"bzronly\", \"upload\" or \"download\").";
38 system "ant";
39}
40elsif($ARGV[0] eq "bzr" || $ARGV[0] eq "bzronly")
41{
42 mkdir "build";
43 die "Could not change into new data dir." if !chdir "build";
44 system "bzr export -v josm_trans lp:~openstreetmap/josm/josm_trans";
45 chdir "..";
46 copypo("build/josm_trans/josm");
47 system "rm -rv build/josm_trans";
48 if($ARGV[0] ne "bzronly")
49 {
50 system "ant";
51 }
52}
53elsif($ARGV[0] eq "upload")
54{
55 potupload();
56}
57elsif($ARGV[0] eq "uploadall")
58{
59 makeupload();
60}
61elsif($ARGV[0] eq "approveall")
62{
63 approveall(dologin());
64}
65elsif($ARGV[0] eq "download")
66{
67 podownload();
68}
69elsif($ARGV[0] eq "stats")
70{
71 getstats();
72}
73else
74{
75 mkdir "build";
76 mkdir "build/josm_trans";
77 die "Could not change into new data dir." if !chdir "build/josm_trans";
78 system "wget $ARGV[0]";
79 system "tar -xf laun*";
80 chdir "../..";
81 copypo("build/josm_trans");
82 system "rm -rv build/josm_trans";
83 system "ant";
84}
85
86sub approveall
87{
88 my ($mech) = @_;
89 print "Trying to approve upload.\n";
90 $mech->get("https://translations.launchpad.net/josm/trunk/+imports?field.filter_status=NEEDS_REVIEW&field.filter_extension=all");
91 my @links;
92 foreach my $line (split("\n", $mech->content()))
93 {
94 push (@links, $1) if $line =~ /href="(\/\+imports\/\d+)"/;
95 }
96 if(!@links)
97 {
98 warn "No upload found in import list, upload possibly failed.";
99 }
100 else
101 {
102 foreach my $link (@links)
103 {
104 eval
105 {
106 print "Approve $link upload.\n";
107 $mech->get("https://translations.launchpad.net$link");
108 $mech->form_with_fields("field.potemplate");
109 $mech->select("field.potemplate", "josm");
110 $mech->click_button(name => "field.actions.approve");
111 };
112 print $@ if $@;
113 }
114 }
115}
116
117sub makeupload
118{
119 my $count = 11;
120 my $outdate = `date -u +"%Y-%m-%dT%H_%M_%S"`;
121 my $mech = dologin();
122 $outdate =~ s/[\r\n]+//;
123 mkdir "build/josm";
124 system "cp po/*.po po/josm.pot build/josm";
125 chdir "build";
126 print "Starting upload ($outdate).\n";
127 if(!$count)
128 {
129 system "tar -cjf launchpad_upload_josm_$outdate.tar.bz2 josm";
130 $mech->get("https://translations.launchpad.net/josm/trunk/+translations-upload");
131 $mech->submit_form(with_fields => {"file" => "launchpad_upload_josm_$outdate.tar.bz2"});
132 sleep(10);
133 }
134 else
135 {
136 my @files = sort glob("josm/*.po");
137 my $num = 1;
138 while($#files >= 0)
139 {
140 my @f = splice(@files, 0, $count);
141 my $file = "launchpad_upload_josm_${outdate}_$num.tar.bz2";
142 print "Create file $file.\n";
143 system "tar -cjf $file ".join(" ",@f);
144 print "Upload file $file.\n";
145 $mech->get("https://translations.launchpad.net/josm/trunk/+translations-upload");
146 $mech->submit_form(with_fields => {"file" => $file});
147 sleep(10);
148 ++$num;
149 }
150 }
151 system "rm -rv josm";
152 chdir "..";
153 approveall($mech);
154}
155
156sub copypo
157{
158 my ($path) = @_;
159 foreach my $name (sort split("\n", `find $path -name "*.po"`))
160 {
161 $name =~ /([a-zA-Z_@]+)\.po/;
162 if($lang{$1})
163 {
164 system("cp", "-v", $name, "po/$1.po");
165 }
166 elsif($cleanall)
167 {
168 local $/; undef $/;
169 open FILE,"<",$name or die;
170 my $x = <FILE>;
171 close FILE;
172 $x =~ s/\n\n.*$/\n/s;
173 open FILE,">","po/$1.po" or die;
174 print FILE $x;
175 close FILE;
176 }
177 }
178}
179
180sub dologin
181{
182 require WWW::Mechanize;
183
184 my $mech = WWW::Mechanize->new("agent" => $agent);
185
186 #$mech->add_handler("request_send" => sub {
187 # my($request, $ua, $h) = @_;
188 # printf "FORM: %s\n", $request->content();
189 # return undef;
190 #});
191 $mech->get("https://translations.launchpad.net/josm/trunk/+login");
192 #print $mech->status() ." - ". $mech->uri()."\n";
193 $mech->submit_form(form_number => 1);
194 getcredits();
195 #print $mech->status() ." - ". $mech->uri()."\n";
196 $mech->submit_form(form_id => "login-form", fields => {"email" => $user, "password" => $pwd});
197 #$mech->dump_headers();
198 #print $mech->status() ." - ". $mech->uri()."\n";
199 #print $mech->content();
200 my $form = $mech->form_name("decideform");
201 die "Could not login.\n" if !$form;
202 my %par = ("yes" => ""); # We need to add "yes" or it does not work
203 foreach my $p ($form->param)
204 {
205 $par{$p} = $form->value($p);
206 }
207 $mech->post($form->action, \%par);
208 #$mech->dump_headers();
209 #print $mech->content();
210 #print $mech->status() ." - ". $mech->uri()."\n";
211 #$mech->dump_forms();
212 return $mech;
213}
214
215sub potupload
216{
217 my $mech = dologin();
218 print "Starting upload.\n";
219 sleep(2);
220 $mech->get("https://translations.launchpad.net/josm/trunk/+translations-upload");
221 chdir("po");
222 $mech->submit_form(with_fields => {"file" => "josm.pot"});
223 print "Start approving of upload.\n";
224 for(1..10)
225 {
226 eval
227 {
228 sleep(10);
229 print "Trying to approve upload.\n";
230 $mech->get("https://translations.launchpad.net/josm/trunk/+imports?field.filter_status=NEEDS_REVIEW&field.filter_extension=pot");
231 my @links;
232 foreach my $line (split("\n", $mech->content()))
233 {
234 if($line =~ /href="(\/\+imports\/\d+)"/)
235 {
236 push (@links, $1);
237 print TXTFILE $line if $debugfile;
238 }
239 }
240 if(!@links)
241 {
242 print TXTFILE $mech->content() if $debugfile;
243 die "Upload not found in import list, upload possibly failed.";
244 }
245 elsif(@links > 1)
246 {
247 die "More than one upload found in import list, cannot approve.";
248 }
249 else
250 {
251 $mech->get("https://translations.launchpad.net$links[0]");
252 if($debugfile)
253 {
254 print TXTFILE "LINK: $links[0]\n";
255 $mech->dump_headers(\*TXTFILE);
256 print TXTFILE $mech->content();
257 print TXTFILE $mech->status() ." - ". $mech->uri()."\n";
258 $mech->dump_forms(\*TXTFILE);
259 }
260 $mech->submit_form(form_name => "launchpadform", button => "field.actions.approve");
261 if(!($mech->content() =~ /There are no entries that match this filtering/))
262 {
263 die "Approving possibly failed.";
264 }
265 }
266 };
267 print $@ if $@;
268 last if !$@;
269 }
270
271 chdir("..");
272}
273
274sub podownload
275{
276 my $mech = dologin();
277 $mech->get("https://translations.launchpad.net/josm/trunk/+export");
278 $mech->submit_form(with_fields => {"format" => "PO"});
279 if(!($mech->content() =~ /receive an email shortly/))
280 {
281 warn "Error requesting file\n";
282 }
283}
284
285sub getcredits
286{
287 if(!$user || !$pwd)
288 {
289 require Term::ReadKey;
290 local undef $/;
291 if(open FILE, "launchpad.pl_credits")
292 {
293 eval <FILE>;
294 close FILE;
295 }
296 elsif(open FILE, "$ENV{HOME}/.josm_i18n_launchpad.pl_credits")
297 {
298 eval <FILE>;
299 close FILE;
300 }
301
302 if(!$user)
303 {
304 Term::ReadKey::ReadMode(4); # Turn off controls keys
305 printf("Enter username: ");
306 for(;;)
307 {
308 my $c = getc();
309 print $c;
310 last if $c eq "\n";
311 $user .= $c;
312 }
313 Term::ReadKey::ReadMode(0);
314 }
315
316 if(!$pwd)
317 {
318 Term::ReadKey::ReadMode(4); # Turn off controls keys
319 printf("Enter password: ");
320 for(;;)
321 {
322 my $c = getc();
323 last if $c eq "\n";
324 print "*";
325 $pwd .= $c;
326 }
327 print "\n";
328 Term::ReadKey::ReadMode(0);
329 }
330 }
331}
332
333sub doget
334{
335 my ($mech, $page, $arg) = @_;
336 for(my $i = 1; $i <= 5; $i++)
337 {
338 $mech->timeout(30);
339 eval
340 {
341 $mech->get($page);
342 };
343 my $code = $mech->status();
344 print "Try $i: ($code) $@" if $@;
345 return $mech if !$@;
346 sleep(30+5*$i);
347 last if $arg && $arg eq "no503" and $code == 503;
348 $mech = WWW::Mechanize->new("agent" => $agent);
349 }
350 return $mech;
351}
352
353sub getstats
354{
355 my %results;
356 require WWW::Mechanize;
357 require Data::Dumper;
358 require URI::Escape;
359 my $mech = WWW::Mechanize->new("agent" => $agent);
360
361 if(open DFILE,"<:utf8","launchpadtrans.data")
362 {
363 local $/;
364 $/ = undef;
365 my $val = <DFILE>;
366 eval $val;
367 close DFILE;
368 }
369
370 binmode STDOUT, ":utf8";
371
372 open FILE,">:utf8","launchpadtrans.txt" or die "Could not open output file.";
373
374 for my $lang (sort keys %lang)
375 {
376 doget($mech, "https://translations.launchpad.net/josm/trunk/+pots/josm/$lang/");
377 sleep(1);
378 my $cont = $mech->content();
379 while($cont =~ /<a href="https?:\/\/launchpad.net\/~(.*?)" class="sprite person(-inactive)?">(.*?)<\/a>/g)
380 {
381 my ($code, $inactive, $name) = ($1, $2, $3);
382 if(exists($results{$code}{$lang}{count}) && exists($results{$code}{$lang}{time}) && time()-$results{$code}{$lang}{time} < 5*24*60*60)
383 {
384 printf "%-5s - %-30s - Found - %s\n", $lang,$code,$name;
385 next;
386 }
387 my $urlcode = URI::Escape::uri_escape($code);
388 $mech = doget($mech, "https://translations.launchpad.net/josm/trunk/+pots/josm/$lang/+filter?person=$urlcode", "no503");
389 sleep(1);
390 my $cont = $mech->content() || "";
391 my ($count) = $cont =~ /of[\r\n\t ]+?(\d+)[\r\n\t ]+?result/;
392 if($count && $mech->status == 200)
393 {
394 my $t = time();
395 my $old = "";
396 if(exists($results{$code}{$lang}{count}))
397 {
398 if($results{$code}{$lang}{count} != $count)
399 {
400 $old .= sprintf " %d %s",abs($count-$results{$code}{$lang}{count}),$count-$results{$code}{$lang}{count} > 0 ? "more" : "less";
401 }
402 else
403 {
404 $old .= " unchanged";
405 }
406 }
407 if(exists($results{$code}{$lang}{time}))
408 {
409 $old .= sprintf " %.2f days later",($t-$results{$code}{$lang}{time})/86400.0;
410 }
411 $results{$code}{NAME} = $name;
412 $results{$code}{TOTAL} += $count-($results{$code}{$lang}{count}||0);
413 $results{$code}{$lang}{count} = $count;
414 $results{$code}{$lang}{time} = $t;
415 $results{$code}{$lang}{$t} = $count;
416 if(open DFILE,">:utf8","launchpadtrans.data")
417 {
418 print DFILE Data::Dumper->Dump([\%results],['*results']);
419 close DFILE;
420 }
421 if($old)
422 {
423 printf "%-5s - %-30s - %5d - %-70s%s\n", $lang,$code,$count,$name,$old;
424 }
425 else
426 {
427 printf "%-5s - %-30s - %5d - %s\n", $lang,$code,$count,$name;
428 }
429 }
430 else
431 {
432 printf "%-5s - %-30s - Skip - %s\n", $lang,$code,$name;
433 }
434 }
435 }
436 for my $code (sort {($results{$b}{TOTAL}||0) <=> ($results{$a}{TOTAL}||0)} keys %results)
437 {
438 next if !$results{$code}{TOTAL};
439 print FILE "$results{$code}{NAME}:$results{$code}{TOTAL}";
440 printf "%5d - %-50s",$results{$code}{TOTAL}, $results{$code}{NAME};
441 for my $lang (sort keys %{$results{$code}})
442 {
443 next if $lang eq "NAME" or $lang eq "TOTAL";
444 next if !exists($results{$code}{$lang}{time}) || time()-$results{$code}{$lang}{time} > 6*24*60*60;
445 print FILE ";$lang=$results{$code}{$lang}{count}";
446 printf " - %-5s=%5d",$lang, $results{$code}{$lang}{count};
447 }
448 print FILE "\n";
449 print "\n";
450 }
451}
Note: See TracBrowser for help on using the repository browser.